home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Gold Collection
/
Software Vault - The Gold Collection (American Databankers) (1993).ISO
/
cdr46
/
p061misc.zip
/
POP.BAT
< prev
next >
Wrap
DOS Batch File
|
1993-03-24
|
4KB
|
114 lines
@ECHO OFF
REM ╒═══════════════════════════════════════════════════════════════════════╕
REM │ SAMPLE POP.BAT │
REM │ Portal Of Power 0.60Γ │
REM ├───────────────────────────────────────────────────────────────────────┤
REM │ THIS EXAMPLE IS BASED ON PORTAL OF POWER, SQUISH AND MAXIMUS │
REM ╞═══════════════════════════════════════════════════════════════════════╡
REM │ NOTE: To optimize the execution-speed of this batch-file, you can │
REM │ remove all REM lines. (But do keep a backup of the original file for │
REM │ future reference) │
REM ╘═══════════════════════════════════════════════════════════════════════╛
:START
C:
CD \PORTAL
PORTAL %1 %2 %3 %4
REM ** The %1 %2 %3 %4 is used for transferring commandline options.
REM ** Eg. 'POP.BAT -n' would cause Portal to start with option -n
REM ┌───────────────────────────────────────────────────────────────────────┐
REM │ ERRORLEVELs 251 to 255 are predefined for error-reporting │
REM └───────────────────────────────────────────────────────────────────────┘
IF ERRORLEVEL 254 GOTO MEMERROR
IF ERRORLEVEL 253 GOTO MODEMERROR
IF ERRORLEVEL 252 GOTO OVRERROR
IF ERRORLEVEL 251 GOTO FOSSILERROR
REM ┌───────────────────────────────────────────────────────────────────────┐
REM │ ERRORLEVELs 200 to 250 are suitable for userdefined errorlevels │
REM └───────────────────────────────────────────────────────────────────────┘
IF ERRORLEVEL 230 GOTO POLLMYBOSS
IF ERRORLEVEL 220 GOTO UNPACK
IF ERRORLEVEL 210 GOTO PACK
REM ┌───────────────────────────────────────────────────────────────────────┐
REM │ ERRORLEVELs 3 to 192 will start the BBS with the correct baud-rate │
REM │ The errorlevel is equal to the Baud-Rate divided by 100 │
REM └───────────────────────────────────────────────────────────────────────┘
IF ERRORLEVEL 192 GOTO BBS
IF ERRORLEVEL 168 GOTO BBS
IF ERRORLEVEL 144 GOTO BBS
IF ERRORLEVEL 120 GOTO BBS
IF ERRORLEVEL 96 GOTO BBS
IF ERRORLEVEL 72 GOTO BBS
IF ERRORLEVEL 48 GOTO BBS
IF ERRORLEVEL 24 GOTO BBS
IF ERRORLEVEL 12 GOTO BBS
IF ERRORLEVEL 3 GOTO BBS
IF ERRORLEVEL 0 GOTO END
REM ** This is equal to 'GOTO END'
REM ┌───────────────────────────────────────────────────────────────────────┐
REM │ Here follows the routine for starting the BBS │
REM └───────────────────────────────────────────────────────────────────────┘
:BBS
BBSBATCH
REM ** Please note that by keeping the BBS-batch as the first, the exe-
REM ** cutions speed of this batchfile is enhanced.
REM ** The BBSBATCH.BAT File Is Written By Portal, And Are Connected To
REM ** SPAWNBBS.BAT
REM ** Your SPAWNBBS.BAT File MUST Start This BatchFile When Finished.
REM ** Therefore There Is No Need For The 'GOTO START' Here.
REM ** Refer To Enclosed SPAWNBBS.BAT For An Example.
REM ┌───────────────────────────────────────────────────────────────────────┐
REM │ Here You Place Your Userdefined Routines (For system-maintenance) │
REM │ The Examples Are Based On SQUISH │
REM └───────────────────────────────────────────────────────────────────────┘
:PACK
SQUISH OUT SQUASH
GOTO START
:UNPACK
SQUISH IN OUT SQUASH
GOTO START
:POLLMYBOSS
SQUISH OUT SQUASH -sPOLLMYBOSS
GOTO START
REM ┌───────────────────────────────────────────────────────────────────────┐
REM │ Here the Errormessages follows: │
REM └───────────────────────────────────────────────────────────────────────┘
:MEMERROR
ECHO Memory Allocation Error - Please Check Your System.
GOTO END
:MODEMERROR
ECHO Error Initializing Modem - Please Check Your Modem, Cabling
ECHO And Your Portal Port And Speed Configuration.
GOTO END
:OVRERROR
ECHO Error Initializing Overlay Manager - Please Check You System
GOTO END
:FOSSILERROR
ECHO No Fossil Loaded - Please Check Your System.
GOTO END
REM ┌───────────────────────────────────────────────────────────────────────┐
REM │ This is the end of this batch-file, DO NOT REMOVE THIS LABEL │
REM └───────────────────────────────────────────────────────────────────────┘
:END